//---------------------------------------------------------------
// Fichero:  solucion05.asy
// Objetivo: Solución del ejercicio 5
// Fecha:    X.13.5.2026
// Autor:    Pedro Reina
// Licencia: CC0 1.0 Universal
//           http://creativecommons.org/publicdomain/zero/1.0/
//---------------------------------------------------------------

// Obtendremos un archivo SVG
settings.outformat="svg";

// Tamaño de la imagen
size(4.2cm);

// Grosor de las líneas
defaultpen(1);

// El ángulo
int Ang = 40;

// El eje de abscisas
draw ((-1.2,0) -- (1.2,0));

// El eje de ordenadas
draw ((0,-1.2) -- (0,1.2));

// La recta auxiliar
draw ((1,-1.2) -- (1,1.2));

// El punto que representa al ángulo
pair P=dir(Ang);

// El punto de corte
pair T = intersectionpoint((1,-3) -- (1,3), -3*P -- 3*P);

// La circunferencia
draw(unitcircle,deepgreen);

// La semirrecta que define el ángulo
draw((0,0) -- 1.5*P, 1.5bp+blue);

// El arco con flecha
draw(arc((0,0),0.35,0,Ang),orange,ArcArrow(SimpleHead,1mm));

// Marcamos los puntos
dot((0,0),3bp+black);
dot(P,3bp+black);
dot((1,0),3bp+red);
dot(T,3bp+red);

// El segmento de la tangente
draw((1,0) -- T, 1.5bp+red);